Mercurial > pidgin3 / file diff

--- /dev/null	Thu Jan 01 00:00:00 1970 +0000
+++ b/libpurple/reference/meson.build	Thu Aug 08 21:34:07 2024 -0500
@@ -0,0 +1,54 @@
+libpurple_doc_content_files = [
+	'contributing.md',
+	'signals_connection.md',
+	'signals_core.md',
+	'tut_c_plugins.md',
+]
+
+if get_option('doc')
+	libpurple_toml = configure_file(
+		input : 'libpurple.toml.in',
+		output : 'libpurple.toml',
+		configuration : version_conf,
+		install : true,
+		install_dir : docs_dir / 'libpurple',
+	)
+
+	libpurple_doc = custom_target('libpurple-doc',
+		input : [ libpurple_toml, libpurple_gir[0] ],
+		output : 'libpurple',
+		command : [
+			gidocgen,
+			'generate',
+			'--quiet',
+			'--fatal-warnings',
+			'--config=@INPUT0@',
+			'--output-dir=@OUTPUT@',
+			'--no-namespace-dir',
+			'--content-dir=@0@'.format(meson.current_source_dir()),
+			'--add-include-path=@0@'.format(meson.global_build_root() / 'subprojects/birb/birb'),
+			'--add-include-path=@0@'.format(meson.global_build_root() / 'subprojects/gplugin/gplugin'),
+			'@INPUT1@'
+		],
+		depend_files : [ libpurple_doc_content_files ],
+		build_by_default : true,
+		install : true,
+		install_dir : docs_dir,
+	)
+
+	test('doc-check',
+		gidocgen,
+		args: [
+			'check',
+			'--config', libpurple_toml,
+			'--add-include-path=@0@'.format(meson.global_build_root() / 'subprojects/birb/birb'),
+			'--add-include-path=@0@'.format(meson.global_build_root() / 'subprojects/gplugin/gplugin'),
+			libpurple_gir[0],
+		],
+		depends: libpurple_gir[0],
+		verbose: true,
+	)
+
+	doc_targets += libpurple_doc
+endif
+