Mercurial > pidgin3 / file revision

feature = get_option('demo')

summary({'Demo': feature.allowed()}, bool_yn: true, section : 'Protocols')

if not feature.allowed()
  subdir_done()
endif

DEMO_SOURCES = [
	'purpledemocommands.c',
	'purpledemocommands.h',
	'purpledemoconnection.c',
	'purpledemoconnection.h',
	'purpledemocontacts.c',
	'purpledemocontacts.h',
	'purpledemoplugin.c',
	'purpledemoplugin.h',
	'purpledemoprotocol.c',
	'purpledemoprotocol.h',
	'purpledemoprotocolactions.c',
	'purpledemoprotocolactions.h',
	'purpledemoprotocolcontacts.c',
	'purpledemoprotocolcontacts.h',
	'purpledemoprotocolconversation.c',
	'purpledemoprotocolconversation.h',
]

demo_resources = gnome.compile_resources('purpledemoresource',
	'resources/purpledemo.gresource.xml',
	source_dir : 'resources',
	c_name : 'purple_demo')
DEMO_SOURCES += demo_resources

shared_library('demo', DEMO_SOURCES,
	c_args : ['-DG_LOG_USE_STRUCTURED', '-DG_LOG_DOMAIN="Purple-Demo"'],
	gnu_symbol_visibility : 'hidden',
	dependencies : [glib, json, libpurple_dep],
	install : true,
	install_dir : PURPLE_PLUGINDIR)

devenv.append('PURPLE_PLUGIN_PATH', meson.current_build_dir())