Mercurial > pidgin3 / file revision

pidgin_doc_content_files = [
]

if get_option('doc')
	pidgin_doc_girs = [
		'--add-include-path=@0@'.format(meson.global_build_root() / 'subprojects/birb-@0@/birb'.format(birb_dep.version())),
		'--add-include-path=@0@'.format(meson.global_build_root() / 'subprojects/gplugin-@0@/gplugin'.format(gplugin_dep.version())),
		'--add-include-path=@0@'.format(meson.global_build_root() / 'subprojects/gplugin-@0@/gplugin-gtk4'.format(gplugin_gtk_dep.version())),
		'--add-include-path=@0@'.format(meson.project_build_root() / 'libpurple'),
	]

	pidgin_toml = configure_file(
		input : 'pidgin.toml.in',
		output : 'pidgin.toml',
		configuration : version_conf,
		install : true,
		install_dir : docs_dir / 'pidgin',
	)

	pidgin_doc = custom_target('pidgin-doc',
		input : [ pidgin_toml, pidgin_gir[0] ],
		output : 'pidgin',
		command : [
			gidocgen,
			'generate',
			'--quiet',
			'--fatal-warnings',
			'--config=@INPUT0@',
			'--output-dir=@OUTPUT@',
			'--no-namespace-dir',
			'--content-dir=@0@'.format(meson.current_source_dir()),
			pidgin_doc_girs,
			'@INPUT1@'
		],
		depends: [ libpurple_gir[0] ],
		depend_files : [ pidgin_doc_content_files ],
		build_by_default : true,
		install : true,
		install_dir : docs_dir,
	)

	test('doc-check',
		gidocgen,
		args: [
			'check',
			'--config', pidgin_toml,
			pidgin_doc_girs,
			pidgin_gir[0],
		],
		depends: [libpurple_gir[0], pidgin_gir[0]],
	)

	doc_targets += pidgin_doc
endif