Mercurial > pidgin3 / file revision

feature = get_option('sip')

feature = feature.disable_if(
  host_machine.system() == 'windows',
  error_message : 'sofia-sip is not currently packaged for windows.')

summary({'SIP': feature}, section : 'Protocols')

if not feature.allowed()
  subdir_done()
endif

SIP_SOURCES = [
	'purplesipplugin.c',
	'purplesipplugin.h',
	'purplesipprotocol.c',
	'purplesipprotocol.h',
]

sofia_sip_ua_dep = dependency('sofia-sip-ua', version : '>=1.12.11')
sofia_sip_ua_glib_dep = dependency('sofia-sip-ua-glib', version : '>=1.12.11')

sip_resources = gnome.compile_resources('purplesipresource',
	'resources/purplesip.gresource.xml',
	source_dir : 'resources',
	c_name : 'purple_sip')
SIP_SOURCES += sip_resources

shared_library('sip', SIP_SOURCES,
	c_args : ['-DG_LOG_USE_STRUCTURED', '-DG_LOG_DOMAIN="Purple-Sip"'],
	gnu_symbol_visibility : 'hidden',
	dependencies : [glib, libpurple_dep, sofia_sip_ua_dep, sofia_sip_ua_glib_dep],
	install : true,
	install_dir : PURPLE_PLUGINDIR)

devenv.append('PURPLE_PLUGIN_PATH', meson.current_build_dir())